계속해서 ping 테스트 하기~

하나 만들어야지 만들어야지 하다가, 오늘에서야 만들었습니다~ 아이구, 이제는 "ping yahoo.co.kr" 16글자 치기도 귀찮아지나 봅니다--; 아래 보이는 그림처럼 ping, ipconfig 메뉴 넣었습니다. ip 랑 gateway ip 는 그냥 arp 명령으로 첫번째 줄에다가 뿌려봤습니다~ 

더운 여름에 보너스 하나~ 시커먼 도스 창 대신에 구미에 맞는 색으로 할 수 있도록 바탕색과 글씨색을 바꿔보았습니다. 저는 시원한 초록색 계열로 싸악~ 더 답답한가요? ㅋ

아래는 소스입니다. (SyntaxHighlighter 라는게 이런 거였군요... 신기합니다. ㅎㅎㅎ)  사용하려면 아래 소스를 긁어다가 파일 확장자를 "cmd" 나 "bat" 로 해서 저장한 후에, 더블클릭해서 사용하시면 됩니다.

@echo off
REM /*********************************************************************/
REM /* Created By  : Mamon                                               */
REM /* Created On  : 13 Aug 2009                                         */
REM /* Version  : 0.2                                                    */
REM /* Description : A simple batch file to check network status         */
REM /*               by using dos command - "ping" and "ipconfig".       */
REM /*********************************************************************/
:: 지역 변수 선언
setlocal

:: 변수 초기화
set strMamom=
set strColorB=
set strColorF=
set cntMamom=0

:: 도스창 제목 바꾸기
title 인터넷 연결 확인하기

:: 물어보기 반복 분기
:ASK

:: 자신의 IP 확인
arp -a

:: 무한루프 방지 체크 구문
set /a cntMamom = cntMamom + 1

echo.
echo 0 : 종료
echo 1 : yahoo.co.kr 로 핑 때려보기
echo 2 : yahoo.co.kr 로 핑 10회 때려보기
echo 3 : 중지할 때까지 yahoo.co.kr 로 핑 때리기(중지는 Ctrl+C)
echo 4 : ip 보기
echo 5 : 화면 색상 바꾸기
echo 6 : 화면 지우기
echo.
set /p strMamom=원하는 메뉴를 선택하세요:

:: 무한루프 검사 구문
if "%cntMamom%" == "99" goto END

:: 사용자 입력에 따라 반응하기
if "%strMamom%" == "0" goto END
if "%strMamom%" == "1" ping yahoo.co.kr
if "%strMamom%" == "2" ping -n 10 yahoo.co.kr
if "%strMamom%" == "3" ping -t yahoo.co.kr
if "%strMamom%" == "4" ipconfig
if "%strMamom%" == "5" goto SETCOLOR
if "%strMamom%" == "6" cls
goto ASK

:: 화면 색상 변경 루틴
:SETCOLOR
echo.
echo 0 : 변경 완료
echo 1 : 초록바탕에 연한 초록글씨
echo 2 : 옥색바탕에 연한 옥색글씨
echo 3 : 노랑바탕에 연한 노랑글씨
echo 4 : 검정바탕에 밝은 흰색글씨
echo 5 : 사용자 입력
echo.
set /p strMamom=원하는 화면을 선택하세요:

:: 사용자 입력에 따라 반응하기
if "%strMamom%" == "0" goto ASK
if "%strMamom%" == "1" COLOR 2A
if "%strMamom%" == "2" COLOR 3B
if "%strMamom%" == "3" COLOR 6E
if "%strMamom%" == "4" COLOR 0F
if "%strMamom%" == "5" goto INPUTCOLOR
goto SETCOLOR

:: 화면 색상 입력루틴
:INPUTCOLOR
echo.
echo   0 = 검정색       8 = 회색
echo   1 = 파랑색       9 = 연한 파랑색
echo   2 = 초록색       A = 연한 초록색
echo   3 = 옥색         B = 연한 옥색
echo   4 = 빨강색       C = 연한 빨강색
echo   5 = 자주색       D = 연한 자주색
echo   6 = 노랑색       E = 연한 노랑색
echo   7 = 흰색         F = 밝은 흰색
echo.
set /p strColorB=원하는 화면 색상(바탕색)을 선택하세요:
set /p strColorF=원하는 글씨 색상을 선택하세요:
COLOR %strColorB%%strColorF%
goto SETCOLOR

:: 종료 분기
:END

:: 지역 변수 해제
endlocal

:: 종료
exit

그럼~~